Fortran Coder

标题: 从N个txt文件中读取相同的一列组成数组用于计算！！ [打印本页]

作者: 274068459 时间: 2017-2-23 17:15
标题: 从N个txt文件中读取相同的一列组成数组用于计算！！
大侠们，新手又来求助了！！！！本人迷迷糊糊写了几行代码。写到后面自己也有点思维混乱了。所以抛出问题，贴出代码希望获得帮助！

！！！！！！！！补充问题，还有一个问题自己完全无能为力了。如何可以从这么多文件中，按照年月日提取我想要的文件，然后再提取所需要的数据列进行计算呢？？？

已将n个txt文件名循环存入一个path.txt文件中。

!!!接下来是利用path.txt中的文件名循环打开这些文件（每一个文件都有多列），并且读出其中的某一列数据，再将这些提取出来的列数据组成一个新的数组写入新的文件用于计算使用。
代码行=================

[Fortran] 纯文本查看 复制代码

program test12   

implicit none



   integer,parameter :: irow = 100   !给一个文件可能的最大数量

   integer,parameter :: iline = 60   !行数

   real,dimension(iline,irow) :: a   !定义一个二维数组用于存放提取的所有数据

   character,dimension(irow) :: b    !定义一个一维数组用于存放名字



   logical :: exceed = .false.



   character(len = 20) :: filename

   integer :: i,j,k

   character :: name

   integer :: nvals = 0

   integer :: status

   integer :: num = 100

   integer :: height

   real :: windspeed1





!!!打开存放文件名的path.txt文件

   open(unit=11,file='path.txt',status='old',action='read',IOSTAT=status)



   if(status /= 0)then



   !!!逐行读取文件名，并保存在数组b中

    do

          read(11,*,iostat=status) name

          

          if(status /=0)EXIT

      nvals = nvals +1

           size:if(nvals<=irow)then

           b(nvals) = name



           else 

        exceed = .true.

           end if size

        end do



    !!!读取数据

        do i=1,nvals

          !根据b(i)的文件名循环打开数据文件

          open(num,file = 'b(i)',status='old',action='read',IOSTAT=status)

                if(status /= 0 )EXIT



         !将前三行说明文件读空

                 do j=1,3

                   read(unit=num,*)

         end do

                

             !读取所要的数据

         do k=1,iline

                   read(2,*) a(k,i)   !2是想要提取的数据列数

                   if(status/=0)EXIT

                 end do



                 if(i>nvals)exit



     end do 



  !!!新建一个文件，将读出的数组写入其中保存用于计算

  open(unit=12,file='windspeed.txt',status='new')



   read(*,*)a



stop

end

！！！！！测试中遇到了一些问题无能为例，截图求助

最后我截图了代码，方便大侠们帮我看

作者: 274068459 时间: 2017-2-23 17:16
小女在代码上面严重感觉智商不足！希望不要被鄙视~~~

作者: li913 时间: 2017-2-23 17:48
你可以看看这两个文件。

QQ截图20170223174744.png (110.22 KB, 下载次数: 395)

作者: vvt 时间: 2017-2-23 18:46
非常好，请 win7 用户摒弃 CVF
详见 http://cvfwin7.w.fcode.cn

作者: fcode 时间: 2017-2-23 18:51
read(unit=num,*)
改为
read( num , * )
或
read( unit=num , format = * )
其他错误见下面的代码，以 !// 为注释

[Fortran] 纯文本查看 复制代码

program test12

  implicit none

  integer,parameter :: irow = 100   !给一个文件可能的最大数量

  integer,parameter :: iline = 60   !行数

  real,dimension(iline,irow) :: a   !定义一个二维数组用于存放提取的所有数据

  character,dimension(irow) :: b    !定义一个一维数组用于存放名字

  logical :: exceed = .false.

  character(len = 20) :: filename

  integer :: i,j,k

  character :: name

  integer :: nvals = 0

  integer :: status

  integer :: num = 100

  integer :: height

  real :: windspeed1

  !!!打开存放文件名的path.txt文件

  open(unit=11,file='path.txt',status='old',action='read',IOSTAT=status)

  if(status /= 0) stop  !// 此行直接改成如果出错，则 stop

  !!!逐行读取文件名，并保存在数组b中

  do

    read(11,*,iostat=status) name

    if(status /=0)EXIT

    nvals = nvals +1

    if(nvals<=irow)then

      b(nvals) = name

    else

      exceed = .true.

    end if

  end do

  !!!读取数据

  do i=1,nvals

    !根据b(i)的文件名循环打开数据文件

    open(num,file = b(i),status='old',action='read',IOSTAT=status) !//此处b(i)不应该带引号

    if(status /= 0 ) cycle !//此处可以用 cycle，第i个文件有错，还可以读第i+1个

    !将前三行说明文件读空

    do j=1,3

      read(num,*) !//此处去掉 unit=

    end do

    !读取所要的数据

    do k=1,iline

      read(2,*) a(k,i)   !2是想要提取的数据列数

      if(status/=0)EXIT

    end do

    if(i>nvals)exit

  end do

  !!!新建一个文件，将读出的数组写入其中保存用于计算

  open(unit=12,file='windspeed.txt',status='new')

  write(*,*)a !//此处应该是 write

  stop

end

作者: 274068459 时间: 2017-2-24 09:16

li913 发表于 2017-2-23 17:48
你可以看看这两个文件。

感谢感谢~但是，我应该从哪里找这两个文件啊？貌似这是个群对吗？我好像下载不了我不在群里

作者: 274068459 时间: 2017-2-24 09:17

vvt 发表于 2017-2-23 18:46
非常好，请 win7 用户摒弃 CVF
详见 http://cvfwin7.w.fcode.cn

谢谢！其实我也想换一个编译器，但是一直都拖着没有做~谢谢你的推荐~我准备换一个了~

作者: 274068459 时间: 2017-2-24 09:18

fcode 发表于 2017-2-23 18:51
read(unit=num,*)
改为
read( num , * )

你总是给与我很直接的帮助！！！

作者: 274068459 时间: 2017-2-24 10:34

fcode 发表于 2017-2-23 18:51
read(unit=num,*)
改为
read( num , * )

您好，首先，我根据上面大侠的建议，更换了编译器~然后根据您的建议修改了程序。但是现在出现了19个错误，貌似还不是编译错误，但是我有点搞不明白这个意思是什么~您能在帮我解答一下吗》

作者: fcode 时间: 2017-2-24 12:38
确保您的 Code::blocks 是包含了 gfortran 编译器的。

然后按照这个操作：

作者: 274068459 时间: 2017-2-28 15:46

fcode 发表于 2017-2-24 12:38
确保您的 Code::blocks 是包含了 gfortran 编译器的。

然后按照这个操作：

我最后生成了windspeed.txt文件，但是文件里面是空的~我计划写进去的数组没有写进去是什么问题？

作者: 274068459 时间: 2017-2-28 15:54

fcode 发表于 2017-2-24 12:38
确保您的 Code::blocks 是包含了 gfortran 编译器的。

然后按照这个操作：

run后有这样一个运行错误提示~

作者: fcode 时间: 2017-2-28 16:26
这是因为你的 a 是一个数组，但是实际只读取了它的一部分。

Ftn95 检查比较严格，当你要输出全部 a 数组的时候，Ftn95 告诉你，有一部分 a 数组没有定义（即没有给值）

其实，a 是一个单变量就可以，不需要定义为数组。

以下为其他错误，见 !//// 开头的注释

[Fortran] 纯文本查看 复制代码

program test12

  implicit none

  real :: a   !//// a 可以不用数组

  character(len=100),dimension(100) :: b    !////要给长度

  logical :: exceed = .false.

  integer :: i,j

  character(len=100) :: name !////要给长度

  integer :: nvals = 0

  integer :: status

  integer :: num = 100

  real    :: xx

  !!!打开存放文件名的path.txt文件

  open(unit=11,file='path.txt',status='old',action='read',IOSTAT=status)

  open(unit=12,file='windspeed.txt') !//// 把这个文件放前面打开

  if(status /= 0) stop  !// 此行直接改成如果出错，则 stop

  !!!逐行读取文件名，并保存在数组b中

  do

    read(11,*,iostat=status) name

    if(status /=0)EXIT

    nvals = nvals +1

    if(nvals<=size(b))then

      b(nvals) = name

    else

      exceed = .true.

    end if

  end do

  !!!读取数据

  do i=1,nvals

    !根据b(i)的文件名循环打开数据文件

    open(num,file = b(i),status='old',action='read',IOSTAT=status) !//此处b(i)不应该带引号

    if(status /= 0 ) cycle !//此处可以用 cycle，第i个文件有错，还可以读第i+1个

    !将前三行说明文件读空

    do j=1,3

      read(num,*) !//此处去掉 unit=

    end do

    !读取所要的数据

    do

      read(num,*,iostat=status) xx , a   !////此处是否应该是read(num ,然后xx是第一列，读了但不使用。要加 iostat

      write(12,*) a !////写入 a

      if(status/=0)EXIT

    end do

    close(num) !////关闭num

  end do

end program test12

实际上，你的代码可以简化为：

[Fortran] 纯文本查看 复制代码

program test12

  implicit none

  real :: a , xx

  integer :: j , num = 100 , status

  character(len=100) :: name !////要给长度

  !!!打开存放文件名的path.txt文件

  open(unit=11,file='path.txt',status='old',action='read',IOSTAT=status)

  if(status /= 0) stop  !// 此行直接改成如果出错，则 stop

  open(unit=12,file='windspeed.txt') !//// 把这个文件放前面打开

  !!!逐行读取文件名，并保存在数组b中

  do

    read(11,*,iostat=status) name

    if(status/=0)EXIT

    open(num,file = name,status='old',action='read',IOSTAT=status) !//此处b(i)不应该带引号

    if(status /= 0 ) cycle !//此处可以用 cycle，第i个文件有错，还可以读第i+1个

    do j=1,3

      read(num,*) !//此处去掉 unit=

    end do

    do

      read(num,*,iostat=status) xx , a   !////此处是否应该是read(num ,然后xx是第一列，读了但不使用。要加 iostat

      if(status/=0)EXIT

      write(12,*) a !////写入 a      

    end do

    close(num) !////关闭num

  end do

  close(11)

  close(12)

end program test12

欢迎光临 Fortran Coder (http://bbs.fcode.cn/)