Fortran Coder

标题: 调用子程序为什么每一次得出的结果都不一样呢 [打印本页]

作者: sqs 时间: 2022-4-3 01:02
标题: 调用子程序为什么每一次得出的结果都不一样呢
在下面的程序当中，我使用gfortran编译器进行编译，但是为什么每次我得到的结果都不一样呢？

[Fortran] 纯文本查看 复制代码

program para

        implicit none

        real(8)::f

        call func(1.0d0,1.0d0)

        print*,f

        end program

        subroutine func(x,y)

                implicit none

                real(8),intent(in) :: x, y

                real(8) :: f

                f = 2*x+3*y

        end subroutine

~                                                                                                                                                                                    

~

得出的结果如下：
另外为什么我这个地方用real,intent(out)::f就会报错呢

问题.png (114.21 KB, 下载次数: 182)

作者: 唐汉 时间: 2022-4-3 01:35
你在主程序里面声明了一个f，在子程序里面又声明了一个f，而且，在子程序里面的f没有输出。像这种情况你可以直接用function，或者subroutine但是加上输出intent(out)

[Fortran] 纯文本查看 复制代码

program main



    use iso_fortran_env, only: real64

    implicit none



    real(real64) :: f

    call func(1._real64, 1._real64, f)

    print *, f



contains



    subroutine func(x, y, ret)

        real(real64), intent(in) :: x, y

        real(real64), intent(out) :: ret



        ret = 2._real64*x + 3._real64*y

    end subroutine func



end program main

作者: sqs 时间: 2022-4-3 13:47

唐汉发表于 2022-4-3 01:35
你在主程序里面声明了一个f，在子程序里面又声明了一个f，而且，在子程序里面的f没有输出。像这种情况你可 ...

好的，那为什么我每次执行a.out的时候输出的结果都不一致呢

作者: gps99 时间: 2022-4-3 20:52

sqs 发表于 2022-4-3 13:47
好的，那为什么我每次执行a.out的时候输出的结果都不一致呢

子程序没有输出位。主程序中的 f等于没有赋值，每次运行 print的是个随机地址的初始值

作者: gps99 时间: 2022-4-3 21:02
本帖最后由 gps99 于 2022-4-3 21:03 编辑

增加输出位是最直接的办法，上面的大咖已经给出代码。

另外，还有个老办法加common公共块。数据块内地址传递，和变量名无关。小程序可以用，数据多的话用module数据块代替

[Fortran] 纯文本查看 复制代码



program para

        implicit none

        real(8)::f

        common /d1/ f

        call func(1.0d0,1.0d0)

        print*,f

end program para



subroutine func(x,y)

        implicit none

        real(8),intent(in) :: x, y

        real(8) :: f

        common /d1/ f

        f = 2*x+3*y

end subroutine func

作者: 布衣龙共 时间: 2022-4-3 21:24
本帖最后由布衣龙共于 2022-4-3 21:29 编辑

楼主这个过程，是非常适合用函数的。
PS：任何程序，无论大小，都不推荐使用common，这东西就让它逝去吧。

[Fortran] 纯文本查看 复制代码

program para

  use , intrinsic :: iso_fortran_env, only: R8 => real64

  implicit none

  write(*,*) func(1.0_R8,1.0_R8)

contains

  Pure real(R8) Function func(x,y) result(f)

    real(R8),intent(in) :: x, y

    f = 2._R8*x+3._R8*y

  End Function func

end program para

作者: sqs 时间: 2022-4-4 15:55

布衣龙共发表于 2022-4-3 21:24
楼主这个过程，是非常适合用函数的。
PS：任何程序，无论大小，都不推荐使用common，这东西就让它逝去吧。
...

啊哈，但是一旦我需要有三四个以上的输出结果，那这个时候就只能使用subroutine而不能使用function了呀，是这样吧

作者: sqs 时间: 2022-4-4 16:05

布衣龙共发表于 2022-4-3 21:24
楼主这个过程，是非常适合用函数的。
PS：任何程序，无论大小，都不推荐使用common，这东西就让它逝去吧。
...

而且我不增加输出端，而是直接对主程序当中的变量进行赋值，这样可以么

[Fortran] 纯文本查看 复制代码

program main

    use iso_fortran_env, only: real64

    implicit none

    real(real64) :: f

    call func(1._real64, 1._real64)

    print *, f

contains

    subroutine func(x, y)

        real(real64), intent(in) :: x, y

        f = 2._real64*x + 3._real64*y

    end subroutine func

end program main

这两者又有什么区别呢

作者: 唐汉 时间: 2022-4-5 02:04

sqs 发表于 2022-4-4 16:05
而且我不增加输出端，而是直接对主程序当中的变量进行赋值，这样可以么[mw_shl_code=fortran,true]progra ...

这样做是可以的，那是因为contains之后的所有子程序依然在一个“scope”里面。你在一个子程序里面也可以用contains来包含一个或多个子程序，他们也会分享上一层子程序的中的变量。但是我不太建议这么做。这样非常容易混淆。当你的程序越写越长了，我还是建议用module把这些都分开。

作者: fcode 时间: 2022-4-6 08:17

sqs 发表于 2022-4-4 16:05
而且我不增加输出端，而是直接对主程序当中的变量进行赋值，这样可以么[mw_shl_code=fortran,true]progra ...

如楼上所言，这样写的话，func函数就和主程序耦合在一起了。
当你需要把 func函数拷贝到其他地方使用时，就会有点“难受”。就不如单纯的解耦之后的函数那样，直接拷贝后直接调用。

对于小型的程序，当然怎么写差别都不大。对于大型程序，为了提高代码的复用性，推荐各程序单元间尽可能解耦。

欢迎光临 Fortran Coder (http://bbs.fcode.cn/)