Fortran Coder

标题: 怎么在文件开头写入数据而不覆盖原有内容？ [打印本页]

作者: 静待花开 时间: 2022-12-25 09:58
标题: 怎么在文件开头写入数据而不覆盖原有内容？
先贴代码

[Fortran] 纯文本查看 复制代码

program main

    implicit none

    integer :: A(5,3), buf(15,1)

    integer :: nsize, irow



    nsize = 5

    A( 1, : ) = [ 5, 4, 8 ]

    A( 2, : ) = [ 4, 1, 9 ]

    A( 3, : ) = [ 3, 4, 8 ]

    A( 4, : ) = [ 1, 2, 8 ]

    A( 5, : ) = [ 3, 1, 0 ]

    Open(Unit=34, File="TimeLog.txt", Form="formatted", Access="sequential", Position='append', Status="old")

    Do irow = 1, 5

       write(34,*)A(irow,:)

    End Do

    Close(34)

    Open(Unit=34, File="TimeLog.txt", Form="formatted", Access="sequential", Position='Rewind', Status="old")

    write(34,'(I9)')nsize

    Close(34)



end

上面代码中，数组A()有5行，就想在 TimeLog.txt 的开头写入一个整数，此数表示后面有5行数据。
上面代码写入nsize后会把前面写入的A都覆盖掉，不知道有没有什么办法，能否不覆盖？我尝试过在写入A之前，先写入一个空行，再写入A，最后再在开头写入nsize。但仍然会覆盖掉A。
因为另外一个程序想读入这个文件，但想在一开头读入这个nsize，从而分配数组大小，再读入A()的内容。

作者: fcode 时间: 2022-12-25 13:04

[Fortran] 纯文本查看 复制代码

program main

  implicit none

  integer :: A(5,3)

  integer :: nsize, irow

  A( 1, : ) = [ 5, 4, 8 ]

  A( 2, : ) = [ 4, 1, 9 ]

  A( 3, : ) = [ 3, 4, 8 ]

  A( 4, : ) = [ 1, 2, 8 ]

  A( 5, : ) = [ 3, 1, 0 ]

  Open(Unit=34, File="TimeLog.txt")

  write(34,100) 0 !//假设暂时不知道大小，先写入一个 0 占位

  Do irow = 1, size(A,1)

    write(34,*) A(irow,:)

  End Do

  Close(34)

  nsize = 5

  Open(Unit=34, File="TimeLog.txt",form="formatted",access="direct",Status="old",recl=9)

  write(34,100,rec=1) nSize

  Close(34)

100 format(i9)

end program main

作者: 静待花开 时间: 2022-12-25 19:42

fcode 发表于 2022-12-25 13:04
[mw_shl_code=fortran,true]program main
implicit none
integer :: A(5,3)

非常感谢您多次帮忙，太感谢了！

欢迎光临 Fortran Coder (http://bbs.fcode.cn/)