IVF调用 C 语言DLL发生错误

ksfengjia · 发表于 2017-2-15 13:48:32

先贴代码

[Fortran] 纯文本查看 复制代码

program s
!<-------------------------------------------------------------------------------------------------------------------------------
use link_cont
use dfwin     !< win api
!<-------------------------------------------------------------------------------------------------------------------------------
implicit none
integer(kind=4)                  :: add
integer(kind=4)                  :: a,b
integer(kind=4)                  :: hwnd
integer(kind=4)                  :: n_case
integer(kind=4)                  :: n_data
integer(kind=4)                  :: lpool
character(len=40), dimension(10) :: c_files  
logical                          :: fail
logical                          :: syslink
!<-------------------------------------------------------------------------------------------------------------------------------
!<-------------------------------------------------------------------------------------------------------------------------------
pointer(add,FileOpenCont) 

hwnd = LoadLibrary('control.dll'C)
if (hwnd <= 0) then
  fail    = .true.
  syslink = .false.
  pause 'DLL Loading failure because control.dll was not found'
else
  write(*,*) 'Succeed Contempt DLL (control.dll) Loading'
  add     = GetProcAddress(hWnd,'FILEOPENCONT'C)  
  call FileOpenCont(n_case,n_data,lpool,c_files)    
endif

end program s

[Fortran] 纯文本查看 复制代码

module link_cont
  interface
    subroutine FileOpenCont (ncase,ndata,lpool,xfiles)
    !MS$ ATTRIBUTES DLLIMPORT :: FileOpenCont
    integer(kind=4) :: ncase
    integer(kind=4) :: ndata
    integer(kind=4) :: lpool
    character(len=40), dimension(10) :: xfiles
    endsubroutine FileOpenCont  
  endinterface
endmodule link_cont

问题描述：
1. 代码为工程使用，用于调用C语言dll库。编译时不需要dll库，所以没有贴出。
2. 此两段代码在CVF下可以编译通过，
而在IVF下编译会报错：error #6401: The attributes of this name conflict with those made accessible by a USE statement. [FILEOPENCONT]
指的是FILEOPENCONT重名，不知道如何修改，让原有功能同时实现，请教各位大大。

fcode · 发表于 2017-2-15 15:02:28

你的写法非常不标准，比如 pointer(add,FileOpenCont)，这就是不对的（尽管IVF允许这样，但是其他编译器会出错）

可以用标准的写法

[Fortran] 纯文本查看 复制代码

module link_cont
  interface
    subroutine I_FileOpenCont (ncase,ndata,lpool,xfiles)
      integer(kind=4) :: ncase
      integer(kind=4) :: ndata
      integer(kind=4) :: lpool
      character(len=40), dimension(10) :: xfiles
    endsubroutine I_FileOpenCont
  endinterface
endmodule link_cont

program s
  use link_cont
  use Kernel32
  use , intrinsic :: ISO_C_Binding !// 标准模块
  implicit none
  type(C_FUNPTR) :: C_FileOpenCont !// C 语言指向函数的指针
  procedure(I_FileOpenCont) , pointer :: FileOpenCont !// fortran 指向函数的指针
  !<-------------------------------------------------------------------------------------------------------------------------------
  integer(kind=4)                  :: add
  integer(kind=4)                  :: hwnd
  integer(kind=4)                  :: n_case
  integer(kind=4)                  :: n_data
  integer(kind=4)                  :: lpool
  character(len=40), dimension(10) :: c_files
  logical                          :: fail
  logical                          :: syslink
  !<-------------------------------------------------------------------------------------------------------------------------------
  hwnd = LoadLibrary('control.dll'//c_null_char)
  if (hwnd <= 0) then
    fail    = .true.
    syslink = .false.
    write(*,*) 'DLL Loading failure because control.dll was not found'
    read(*,*)
  else
    write(*,*) 'Succeed Contempt DLL (control.dll) Loading'
    add     = GetProcAddress(hWnd,'FILEOPENCONT'//c_null_char) !//获得地址（整数）
    C_FileOpenCont = transfer( add , C_FileOpenCont ) !//把整数的地址转换成 C 指针
    call C_F_PROCPOINTER( C_FileOpenCont , FileOpenCont ) !//把C指针转换成 fortran 指针
    call FileOpenCont(n_case,n_data,lpool,c_files)
  endif
end program s

ksfengjia · 发表于 2017-2-15 15:55:45

非常感谢，已测试过代码完全可以。
原有代码比较老，想进行转化，确实有很多古老的写法。

另：我想知道，为何原有代码ivf编译会出现变量名冲突的问题，而cvf不报错？

fcode · 发表于 2017-2-15 16:02:41

因为 pointer(add,FileOpenCont) 这种写法本身就是不规范的，语法并不允许这样。我也不知道为什么 CVF 不报错~~

pasuka · 发表于 2017-2-15 16:10:16

ksfengjia 发表于 2017-2-15 15:55
非常感谢，已测试过代码完全可以。
原有代码比较老，想进行转化，确实有很多古老的写法。

若是仅考虑Windows平台下使用，完全可以虚拟机安装XP和cvf进行编译，再拷贝dll出来
后续开发工作，可以在保持接口函数不变的情况下另起炉灶

[混编] IVF调用 C 语言DLL发生错误

回帖奖励 +10 元F 币

回帖奖励 +10 元F 币

美女勋章

热心勋章

星光勋章

新人勋章

贡献勋章

管理勋章

帅哥勋章

爱心勋章

规矩勋章

元老勋章

水王勋章


30 元F 币	回复本帖可获得 10 元F 币奖励! 每人限 1 次