关于fortran里指针的讨论

btx97

因为听说高手都是指针用的比较多的，所以最近在考虑fortran里指针的作用。特意发帖希望高手们能来一起讨论下，让我们学习中的新人长点知识。:lol:lol
在fortran 95/2003 for scientists and engineerings 书中指出，在数组交换的过程中，用指针交换的效率明显比用普通变量交换的效率要高。　所以自己写代码比较了一下效率，代码为

[Fortran] 纯文本查看 复制代码

program test_pointer
  implicit none
  real, dimension(100,100), target :: array1, array2
  real, dimension(:,:), pointer :: p1, p2, temp_p
  real, dimension(100,100) :: a1, a2, temp

  integer :: i
  real :: begin, end

  call random_number(a1)
  call random_number(a2)

  array1=a1
  array2=a2

  p1=>array1
  p2=>array2
  call cpu_time(begin) 
  do i=1,1000000
     temp=a1
     a1=a2
     a2=temp
  end do
  call cpu_time(end)
     
  write(*,*) 'Time of variable exchange:', end-begin

  call cpu_time(begin)
  do i=1,1000000
     temp_p=>p1
     p1=>p2
     p2=>temp_p
  end do
  call cpu_time(end)

  write(*,*) 'Time of pointer exchange:', end-begin

end program test_pointer

运行结果为：

[Shell] 纯文本查看 复制代码

$ ./a.out 
 Time of variable exchange:   4.5159998    
 Time of pointer exchange:  8.00037384E-03

可以发现用指针的确比用普通变量有效。
不过我还有个疑问希望高手能解答下。　fortran中指针所占内存的是不是比它的Target要少很多？　　因为如果fortran中指针所占内存跟它的Target一样，那么虽然代码效率是提高了，但所耗资源也提高了不少，就不见得很经济。　

此外，指针在链表里的应用很多书上都讲了。我觉得我们可以先不考虑指针在结构数据的应用。

十分希望各位高手能把自己使用指针的经验体会拿出来分享下，　共同讨论下fortran中指针的优缺点。

楚香饭

btx97 发表于 2014-2-21 16:33
c 语言有指针数组和数组指针的区别，但fotran里好像没有这样的区别吧。

我的例子程序中p1指向了一个数组 ...

Fortran 里只有数组指针，指针数组可以像 8 楼的代码那样。

你的程序里 p1 是数组指针。p1 是指针，不是数组，只不过它指向的目标是数组。

p1(i,j) 可以取出对应的变量值，但 p1 依然是指针，不是数组。

关于指针 p+1 ，实现是非常容易的。只是地址加上每元素占用的字节数既可。但是 Fortran 语法不允许，目的是防止指针指向数组范围之外。

Fortran 指向数组的指针（数组指针），不单单是数组的首地址，而且包含数组的维度和上下限，因此，更可有效防范指针指向数组范围之外。

从编译器实现上看，Fortran的指针是受约束的，实现起来更难（换句话说，写一个支持指针的 Fortran 编译器，比写一个支持指针的 C 编译器难得多）。受约束会影响灵活性，但可增加数据安全。

这就好像 Discuz 论坛（咱们论坛使用的程序）一样，它使用了大量的代码来限制普通会员的 HTML 使用，比如会员发帖时输入 <iframe src="某恶意网址">，论坛程序会对这段代码进行改动，使得它并不会被浏览器当做插入页面来解释，所以在论坛发帖的时候你做不出漂亮的网页效果。但是，对论坛来说更安全。

最后，指向普通变量的指针，不能直接指向一个数组，但可以指向数组的某个元素，或者 type 派生类型的某一个普通变量成员。

[Fortran] 纯文本查看 复制代码

real ,pointer :: p
real , target :: a( 10 )
integer :: i
Do i = 1 , 10
 p => a(i)
End Do

btx97

delta 发表于 2014-2-21 10:08
膜拜各位大虾

Fortran还不支持指针数组，不然在数值计算中也可以经常用用的 ...

c 语言有指针数组和数组指针的区别，但fotran里好像没有这样的区别吧。

我的例子程序中p1指向了一个数组，这是数组指针的概念的吧。
但p1本身也是个数组，p1(i,j)可以取出所对应的变量值，这个是指针数组的概念吧。

c语言里可以移动一个指针到指定内存单元，如p+1。fortran里好像没这个功能。
而且fortran里也不能拿单个(非数组)指针去指向一个数组。
我哪说错了，你们随便指正哈。学习中，有人指出错误很重要。

楚香饭

这里写 Fortran 代码有个 bug

p(:) 会被替换成表情。得写成 p( : )

楚香饭

delta 发表于 2014-2-21 10:08
膜拜各位大虾

Fortran还不支持指针数组，不然在数值计算中也可以经常用用的 ...

有一个像是“耍赖皮”的方法使用指针数组。

[Fortran] 纯文本查看 复制代码

type pST_Array
  real , pointer :: p( : )
end type pST_Array
Type ( pST_Array) , pointer :: pA( : )
integer :: i , j
Allocate( pA( 10 ) ) !// 产生10个指向数组的指针。
Do i = 1 , 10
  Allocate( pA(i)%p(2) ) !// 每个指针指向一个2元素数组
  Do j = 1 , 2
    pA(i)%p(j) = i*100+j
  End Do
End Do
Do i = 1 , 10
  write( * , * ) pA(i)%p( : )
End Do  
!// 尚未书写释放指针代码
End Program

delta

膜拜各位大虾

Fortran还不支持指针数组，不然在数值计算中也可以经常用用的

fcode

指向单变量的指针也是可以用的。

譬如，以前要相同的处理两个量。需要写两种可能，有了指针，只写一种就可以了。

[Fortran] 纯文本查看 复制代码

real :: rAmp , rPhz
if ( ... )
  call proc( rAmp )
  rAmp = func( rAmp )
  call write( rAmp )
else
  call proc( rPhz )
  rPhz = func( rPhz )
  call write( rPhz )
end if

用指针的话，可以很简单的写为：

[Fortran] 纯文本查看 复制代码

real , target :: rAmp , rPhz
real , pointer :: p
if ( ... )
  p => rAmp
else
  p => rPhz
end if
call proc( p )
p = func( p )
call write( p )

当然了，把那三句话写成子程序，用 rAmp 和 rPhz 分别做参数，也可以。但是相对还是麻烦些

btx97

chuxf 发表于 2014-2-20 09:49
Fortran 的指针具有特殊性。一般来说，所占的内存比它的Target要少很多很多。

if 指向单变量或结构体 then ...

谢谢讲解，又增长了点知识。

这样看来用指针指向大型数组是比较划算的:lol。　

单个变量是不是就不怎么样了，因为一个real好像也是４字节吧。　

另外也谢谢jason388和fcode能说出自己对指针的理解。

fcode

楼上说得没错，严谨和灵活往往不可兼得。

实际上，Fortran 的参数默认是传址的，一定程度上就是指针。所以语法层面上不使用指针也能完成很多事情。

而 C 的参数默认是传值的，如果语法层面上也不使用指针，很多事情就捉襟见肘。

我对指针还是抱有挺乐观的观点的，如果有大量数据的操作，合理应用指针可以提高程序执行效率。

但稍不熟练就容易造成内存里分配了数据，指针都指走了，导致占用内存而且无法使用，如果这样的情况出现在循环里，就是内存泄露，情况就遭了。

jason388

Fortran指针是Fortran90标准引进的，之前Fortran中没有指针（编译器扩展除外），所以Fortran77高手基本上不使用指针。

Fortran的强项在于数组操作，所以学习Fortran一定要下功夫学好数组相关的内容。

在Fortran中，指针一般用在一些特殊的场合，比如链表等动态数据结构的实现，与C的互操作以及楼主提到的通过地址操作才能实现高效的少数场合。指针的缺点是容易出现内存泄漏和dangling pointers，因此应用要非常小心。除此之外，可用于可分配数组的一些内部函数也不能用于指针。