多项式曲线拟合

1121865306

多项式曲线拟合，求助。
有一组数据，想求得多项式拟合的表达式。
有没有编好的，或者IMSL里多项式拟合的方法。
自己写好难，也比较着急。
跪谢！！

LYH

有人解答一下吗

LYH

这行代码(093)没有问题吗，Y=Y*X+POLY_COEF(POLY_ORDER+1-I)对于这一行计算公式我并没有看懂，有谁能解释一下吗，不是一个13阶的多项式吗，还有067行，为什么POLY_COEF=MATMUL(C,B)是这样写呢，不是ATAU=ATB吗

maomaolover

kerb 发表于 2017-11-20 15:58
这是我写的一个，希望对你有用

全域拉格朗日插值其实就是多项式插值，只是一般教科书的讲解形式，让很多人 ...

确实给力

luott_33

kerb 发表于 2017-11-20 15:58
这是我写的一个，希望对你有用

全域拉格朗日插值其实就是多项式插值，只是一般教科书的讲解形式，让很多人 ...

067行少了一步矩阵求逆？

rovingboy

其他都看懂了，最后一段的上面这个代码不知道意义何在？这个时候的A不是除了对角线为1，其他都为0吗？ 而且这个A值也没有返回其他程序里面，为什么需要这一段呢？

rovingboy

   DO L=N,1,-1
         IF(INDXR(L).NE.INDXC(L))THEN
           DO K=1,N
             DUM=A(K,INDXR(L))
             A(K,INDXR(L))=A(K,INDXC(L))
             A(K,INDXC(L))=DUM
          ENDDO
        ENDIF
   ENDDO

渡箭

很给力！

kerb

这是我写的一个，希望对你有用

全域拉格朗日插值其实就是多项式插值，只是一般教科书的讲解形式，让很多人忽略了这一点。高阶多项式插值会引起容格现象，也就是说虽然多项式插值会经过已知点，但是会引起数值震荡。
最小二乘法适用于数据拟合，最常见的是那种线性拟合，其实也可以用已知的曲线的组合去拟合给定的数据。曲线可以有多种选择，比如光谱曲线往往用高斯曲线或者洛仑兹曲线的组合去拟合，当然也可以用多项式曲线去拟合，只是缺少了物理意义，但是这个时候，可以把这种拟合的曲线理解为插值曲线，给出数值区间任意点的函数值。

问题描述：已知一组数据点(XT,YT)，这些点的总数是M，我们希望用一个N阶的多项式去拟合这些数据，假设这个多项式的系数用数组U表示，记住一个N阶的多项式，有N+1个系数（包括常数项），求的多项式系数，多项式就确定了。

Y(1)=U(1)+U(2)*X(1)+U(3)*X(1)^2+...+U(N+1)*X(1)^N
Y(2)=U(1)+U(2)*X(2)+U(3)*X(2)^2+...+U(N+1)*X(2)^N
......................................................................................
Y(M)=U(1)+U(2)*X(M)+U(3)*X(M)^2+...+U(N+1)*X(M)^N
记
Y=(Y(1),Y(2),...,Y(M))^T，U=(U(1),U(2),...,U(N))
矩阵A的元素是A(i,j)=X(i)^j，1<=i<=M，0<=j<=N，A是MxN的
上面的方程组可以写成：
AU=Y
如果M<N，这个时候有无穷多解，但是无法解释每个解的物理含义；如果M=N，且A非奇异，这个时候可以解得一组数据，这个时候其实就是求多项式插值；当M>N，这是超定方程组，理论上只能求得最小二乘解，记A^T表示矩阵A的转置矩阵
(A^T*A)U=(A^T*Y)，解出U就求出多项式系数。

下面的程序中：
POINTS_NUM表示已知点的数目，即上面说的M
POLY_ORDER,表示多项式阶数，即上面说的N
POLY_COEF多项式系数，数组
XT，YT已知点，数组

[Fortran] 纯文本查看 复制代码

PROGRAM MAIN !主程序
    IMPLICIT NONE
    INTEGER,PARAMETER::POINTS_NUM=15 !这个是测试点的数目，你应该根据你的测试点数修改它
    INTEGER,PARAMETER::POLY_ORDER=13 !如果是线性拟合：POLY_ORDER=1
    INTEGER,PARAMETER::DP=KIND(1.D0)
    REAL(KIND=DP)::A(POINTS_NUM,POLY_ORDER+1),POLY_COEF(POLY_ORDER+1) !如果是线性拟合，实际上就是POLY_COEF(2)：y = ax + b
    REAL(KIND=DP)::XT(POINTS_NUM),YT(POINTS_NUM),DX,XN(POINTS_NUM),YN(POINTS_NUM)
    INTEGER::INFO
    INTEGER::I
   !XT,YT为测试的数据
    XT=(/0.1D0,0.2D0,0.3D0,0.4D0,0.5D0,0.6D0,0.7D0,0.8D0,0.9D0,0.92D0,0.94D0,0.96D0,0.98D0,0.99D0,0.995D0/)!插值节点
    YT=(/0.86D0,0.78D0,0.71D0,0.66D0,0.59D0,0.52D0,0.45D0,0.36D0,0.23D0,0.19D0,0.16D0,0.12D0,0.07D0,0.04D0,0.02D0/)!插值节点函数值
    !XN=(/0.15D0,0.985D0,0.995D0/)!待计算的插值点
    !YN=(/0.86060402972635042,5.30099995722376274E-002,2.57654880479794013E-002/)!插值结果
    DX=1.D0/15
    CALL LSINTERPOLY(POINTS_NUM,XT,YT,POLY_ORDER,POLY_COEF,INFO)
    WRITE(*,*)
    WRITE(*,*)
    IF(INFO/=-1)THEN
        DO I=1,15
            XN(I)=XT(I)
            CALL POLY_VALUE(POLY_ORDER,POLY_COEF,XN(I),YN(I))
            !WRITE(*,FMT="(4X,A,G0,A,G0)")"YN(",XN(I),")=",YN(I)
            WRITE(*,FMT="(F6.4,2X,G0)")YN(I),YN(I)-YT(I)
        END DO
    ELSE
        WRITE(*,*)"ERROR"
    ENDIF
    READ(*,*)
END PROGRAM MAIN
!---------------------------------------------------------------------------
SUBROUTINE LSINTERPOLY(POINTS_NUM& !测试数据的个数
                                          ,XT& !测试数据横坐标
                                          ,YT& !测试数据纵坐标
                                          ,POLY_ORDER& !多项式阶数
                                          ,POLY_COEF& !多项式系数
                                          ,INFO& !输出信息，INF=0，求解成功，INFO=-1求解失败
                                          )!求多项式系数
    IMPLICIT NONE
    INTEGER,PARAMETER::DP=KIND(1.D0)
    INTEGER,INTENT(IN)::POINTS_NUM,POLY_ORDER
    REAL(KIND=DP),INTENT(IN)::XT(POINTS_NUM),YT(POINTS_NUM)
    REAL(KIND=DP),INTENT(OUT)::POLY_COEF(POLY_ORDER+1)
    INTEGER,INTENT(OUT)::INFO
    LOGICAL::SOL_OK
    REAL(KIND=DP)::A(POINTS_NUM,POLY_ORDER+1),ATA(POLY_ORDER+1,POLY_ORDER+1)
    REAL(KIND=DP)::B(POINTS_NUM),C(POLY_ORDER+1,POINTS_NUM)
    INTEGER::I,J
    IF(POLY_ORDER+1>POINTS_NUM)THEN
        INFO=-1
        RETURN
    END IF
    INFO=0
    A=0.D0
    DO I=1,POINTS_NUM
        DO J=0,POLY_ORDER
            IF(J==0)THEN
                A(I,J+1)=1.D0
            ELSE
                A(I,J+1)=XT(I)**J
            ENDIF
        END DO
    END DO
    B=YT
    C=TRANSPOSE(A)
    ATA=MATMUL(C,A)
    POLY_COEF=MATMUL(C,B)
   
!    IF(POLY_ORDER+1==POINTS_NUM)THEN
!        CALL SOLVE(A,POLY_ORDER+1,POLY_COEF,SOL_OK)
!    ELSE
!        CALL SOLVE(ATA,POLY_ORDER+1,POLY_COEF,SOL_OK)
!    END IF
    CALL SOLVE(ATA,POLY_ORDER+1,POLY_COEF,SOL_OK)

    IF(SOL_OK)THEN
        INFO=0
    ELSE
        INFO=-1
    END IF
    RETURN
END SUBROUTINE
!---------------------------------------------------------------------------
SUBROUTINE POLY_VALUE(POLY_ORDER,POLY_COEF,X,Y)!根据多项式计算插值点(X)的函数值Y
    IMPLICIT NONE
    INTEGER,PARAMETER::DP=KIND(1.D0)
    INTEGER,INTENT(IN)::POLY_ORDER
    REAL(KIND=DP),INTENT(IN)::POLY_COEF(POLY_ORDER+1),X
    REAL(KIND=DP),INTENT(OUT)::Y
    INTEGER::I
    Y=0.D0
    DO I=0,POLY_ORDER
        Y=Y*X+POLY_COEF(POLY_ORDER+1-I)
    END DO
    RETURN
END SUBROUTINE
!---------------------------------------------------------------------------
SUBROUTINE SOLVE(A,N,B,SOL_OK)!全选主元高斯消元回带法求解器
    IMPLICIT NONE
    INTEGER,PARAMETER::DP=KIND(1.D0)
    INTEGER,INTENT(IN)::N
    LOGICAL,INTENT(OUT)::SOL_OK
    REAL(KIND=DP),INTENT(INOUT)::A(N,N)
    REAL(KIND=DP),INTENT(INOUT)::B(N)
    REAL(KIND=DP)::BIG,DUM,PIVINV,TEMP
    INTEGER I,ICOL,IROW,J,K,L,LL,INDXC(N),INDXR(N),IPIV(N)
    SOL_OK=.TRUE.
    DO J=1,N
        IPIV(J)=0
    ENDDO
    DO I=1,N
        BIG=0.D0
        DO J=1,N
            IF(IPIV(J).NE.1)THEN
                DO K=1,N
                    IF (IPIV(K).EQ.0) THEN
                        IF (ABS(A(J,K)).GE.BIG)THEN
                            BIG=ABS(A(J,K))
                            IROW=J
                            ICOL=K
                        ENDIF
                    ELSEIF (IPIV(K).GT.1) THEN
                        WRITE(*,*)'SINGULAR MATRIX IN GAUSSJ'
                        SOL_OK=.FALSE.
                    ENDIF
                ENDDO
            ENDIF
        ENDDO
        IPIV(ICOL)=IPIV(ICOL)+1
        IF (IROW.NE.ICOL) THEN
            DO L=1,N
                DUM=A(IROW,L)
                A(IROW,L)=A(ICOL,L)
                A(ICOL,L)=DUM
            ENDDO
            DUM=B(IROW)
            B(IROW)=B(ICOL)
            B(ICOL)=DUM
        ENDIF
        INDXR(I)=IROW
        INDXC(I)=ICOL
        TEMP=ABS(A(ICOL,ICOL))
        IF(A(ICOL,ICOL)==0.D0)THEN
            WRITE(*,*) 'SINGULAR MATRIX IN GAUSSJ'
            SOL_OK=.FALSE.
            RETURN
        ENDIF
        PIVINV=1.D0/A(ICOL,ICOL)
        A(ICOL,ICOL)=1.D0
        DO L=1,N
            A(ICOL,L)=A(ICOL,L)*PIVINV
        ENDDO
        B(ICOL)=B(ICOL)*PIVINV
        DO LL=1,N
            IF(LL.NE.ICOL)THEN
                DUM=A(LL,ICOL)
                A(LL,ICOL)=0.D0
                DO L=1,N
                    A(LL,L)=A(LL,L)-A(ICOL,L)*DUM
                ENDDO
                B(LL)=B(LL)-B(ICOL)*DUM
            ENDIF
        ENDDO
    ENDDO
    DO L=N,1,-1
        IF(INDXR(L).NE.INDXC(L))THEN
            DO K=1,N
                DUM=A(K,INDXR(L))
                A(K,INDXR(L))=A(K,INDXC(L))
                A(K,INDXC(L))=DUM
            ENDDO
        ENDIF
    ENDDO
    RETURN
END SUBROUTINE SOLVE

taipinghu

1121865306 发表于 2016-4-25 21:42
已经找到例子了，谢谢平台

楼主方便传阅一下例子吗？最近在搞这个问题。  谢谢楼主！