请问压缩包里面的文件您怎么调用呢，在哪儿设置的呢？

fcode 发表于 2023-2-12 11:39
不好说，我手上没有高版本的matlab，也没有资料。
从编程的角度，对64位系统来说，用于存放地址的变量，肯 ...

好的好的，感谢您的回复！

不好说，我手上没有高版本的matlab，也没有资料。
从编程的角度，对64位系统来说，用于存放地址的变量，肯定是需要kind=8的。
其他的如果不确定，可以先定义成kind=8的，看看它的值会不会超过kind=4的上限（2147483648），如果超过了，那一般就需要kind=8

fcode 发表于 2023-2-10 23:38
你看的资料应该是针对32位的。而你用的64位，所以略有区别。一些变量需要定义为kind=8的才可以。

看注释

感谢您！问题已解决！我还想问一下，哪些变量需要定义成kind=8，我翻了翻matlab的帮助里，有一部分变量并没有提到必须定义成kind=8，有没有关于这个问题的参考资料？再次感谢！

你看的资料应该是针对32位的。而你用的64位，所以略有区别。一些变量需要定义为kind=8的才可以。

看注释

[Fortran] 纯文本查看 复制代码

MODULE MATLAB
  IMPLICIT NONE
  INTEGER(8)::EP !//kind=8
  integer :: STATUS
  INTEGER(8),EXTERNAL:: engOpen ,engPutVariable , engGetVariable ,engEvalString,engClose!//kind=8
  INTEGER(8),EXTERNAL:: mxCreateDoubleMatrix, mxGetPr!//kind=8
CONTAINS
  SUBROUTINE STARTMATLAB()
    WRITE(*,*) '正在打开matlab程序，请稍后...'
    EP = engOpen('matlab')
    IF(EP == 0) THEN
      WRITE(*,*) '无法打开matlab'
      STOP
    ELSE
      WRITE(*,*) '成功打开matlab'
    ENDIF
  END SUBROUTINE STARTMATLAB

  SUBROUTINE CLOSEMATLAB()
    WRITE(*,*) '正在关闭matlab程序，请稍后...'
    STATUS = engClose(EP)
    IF(STATUS /= 0) THEN
      WRITE(*,*) '无法关闭matlab'
      STOP
    ELSE
      WRITE(*,*) '成功关闭matlab'
    ENDIF
  END SUBROUTINE CLOSEMATLAB

  SUBROUTINE MC(STRING)
    CHARACTER(LEN=*)::STRING
    PRINT * , '正在matlab中计算语句：     ', STRING

    IF(engEvalString(EP,STRING) /= 0) THEN
      WRITE(*,*) 'engEvalString failed'
      STOP
    ENDIF
  END SUBROUTINE MC

  SUBROUTINE F2M(FDATA,MSTRING,ROW,COL)
    INTEGER :: ROW,COL
    REAL(8),DIMENSION(ROW,COL) :: FDATA!//kind=8
    CHARACTER(LEN=*) :: MSTRING
    INTEGER(8) :: PTEMP!//kind=8
    PTEMP = mxCreateDoubleMatrix(ROW,COL,0)

    IF (PTEMP == 0) THEN
      WRITE(*,*) '无法申请到内存'
      STOP
    ENDIF
    CALL mxCopyReal8ToPtr(fdata,mxGetPr(ptemp),ROW*COL)

    STATUS = engPutVariable(EP, MSTRING,PTEMP)
    CALL mxDestroyArray(PTEMP)

    PRINT * , '正在matlab中生成矩阵：     ', MSTRING
    IF(STATUS /= 0) THEN
      WRITE(*,*) 'engPutVariable failed'
      STOP
    END IF
  END SUBROUTINE F2M

  SUBROUTINE M2F(MSTRING,DDATA,ROW,COL)
    INTEGER :: ROW,COL
    REAL(8),DIMENSION(ROW,COL) :: DDATA!//kind=8
    CHARACTER(LEN=*) :: MSTRING
    INTEGER(8) :: PTEMP!//kind=8
    PTEMP = engGetVariable(EP,MSTRING)
    CALL mxCopyPtrToReal8( mxGetPr(ptemp),DDATA,ROW*COL)
  END SUBROUTINE M2F

END MODULE MATLAB

PROGRAM MAIN
  USE MATLAB
  IMPLICIT NONE
  INTEGER,PARAMETER::NDATA = 10
  REAL(8),DIMENSION(NDATA)::X,Y,Z
  INTEGER::M
  DO M = 1,NDATA
    X(M) = 3.14159*(M-1)/(NDATA-1)
    Y(M) = SIN(X(M))
  ENDDO
  CALL STARTMATLAB()
  CALL F2M(X,'X',1,NDATA)
  CALL F2M(Y,'Y',1,NDATA)
  CALL MC("plot(X,Y);title('y=sin(x)');xlabel('x');ylabel('y')")
  CALL MC('Z=2*Y;')!//matlab区分大小写
  CALL M2F('Z',z,1,NDATA)!//matlab区分大小写
  PRINT * ,'      X      ' ,'      Y      ','      Z      ','   2*Y'
  DO M = 1,NDATA
    WRITE(*,'(G15.6,G15.6,G15.6,G15.6)') X(M),Y(M),Z(M),2*Y(M)
  ENDDO

END PROGRAM MAIN