请问怎么获得包括子文件夹的所有文件名

kyra

[Fortran] 纯文本查看 复制代码

If ( ( stInfo%permit.AND.FILE$DIR ) == 0 ) then
  call CallBack( Trim(stInfo%Name) , iTotal + 1 )
  iTotal = iTotal + 1
Else
  call DoWithWildcard( ... ) !!!文件夹，递归
End If

kyra

callBack 是接口，ToDoOneFile 是它的真实实现。

[Fortran] 纯文本查看 复制代码

Program www_fcode_cn
   Implicit None
   integer :: n = 0
   External ToDoOneFile
   call DoWithWildcard( "C:\dosh\*" , ToDoOneFile , n )
   write(*,*) '共',n,'个文件'
End Program www_fcode_cn

Subroutine ToDoOneFile( cFile , iLoop )
   Character( Len = * ) , Intent( IN ) :: cFile
   Integer , Intent( IN ) :: iLoop
   Write( * , * ) '第',iLoop,'个文件：',cFile
   !Open( 12 , File = cFile )
   !Read( 12 )
   !Close( 12 )
End Subroutine ToDoOneFile
   
Recursive Subroutine DoWithWildcard(cWildcard,CallBack,iTotal)
   !// 下一句代码，如果是 Compaq 或 Digital，需改为 Use DFLib
   Use IFPort , only : GetFileInfoQQ , GetLastErrorQQ , FILE$INFO , FILE$LAST , FILE$ERROR , FILE$FIRST , ERR$NOMEM , ERR$NOENT , FILE$DIR
   Implicit None
   Interface 
     Subroutine CallBack( cFile , iLoop )
       Character( Len = * ) , Intent( IN ) :: cFile
       Integer , Intent( IN ) :: iLoop
     End Subroutine CallBack
   End Interface
   Character( Len = * ) , Intent( IN ) :: cWildcard
   Integer , Intent( OUT ) :: iTotal
   Type (FILE$INFO) :: stInfo
   Integer(4) :: iWildhandle , iLength , iRet
   iWildhandle = FILE$FIRST
   Do While (.TRUE.)
       iLength = GetFileInfoQQ( cWildCard , stInfo , iWildhandle )
       If (( iWildhandle == FILE$LAST) .OR.( iWildhandle == FILE$ERROR )) then
         Select Case (GetLastErrorQQ())
         Case (ERR$NOMEM)  !//内存不足
           iTotal = - 1
           return
         Case (ERR$NOENT)  !//碰到通配符序列尾
           return
         Case Default
           iTotal = 0
           return
         End Select
       End If
       iLength = index( cWildcard , "\" , .true. )
       If ( ( stInfo%permit.AND.FILE$DIR ) == 0 ) then
         call CallBack( cWildcard(:iLength)//trim(stInfo%Name) , iTotal + 1 )
         iTotal = iTotal + 1
       Else         
         if(stInfo%Name(1:1) /= "." ) then           
           call DoWithWildcard( cWildcard(:iLength)//trim(stInfo%Name)//"\"//cWildcard(iLength+1:) , CallBack , iTotal )
         end if
       End If
   End Do
 End Subroutine DoWithWildcard

kyra

这中间涉及到很多问题，比如重名怎么办？
比如

有2个文件，分别叫
1234567890123.txt
1234567890124.txt

还有中文字符怎么办？比如
我是1个中文文件名.txt

等等。

如果你只是重命名，我觉得批处理比较适合你。

kyra

你是想获得短路径吧？

不妨试试 windows 提供的 GetShortFileName

[Fortran] 纯文本查看 复制代码

Subroutine ToDoOneFile( cFile , iLoop )
  use Kernel32 , only : GetShortPathName
  use , intrinsic :: ISO_C_Binding
   Character( Len = * ) , Intent( IN ) :: cFile
   Integer , Intent( IN ) :: iLoop
   integer :: k
   character(len=512) :: sFile
   k = GetShortPathName( trim(cFile)//c_null_char , sFile , len(sFile) ) 
   Write( * , * ) '第',iLoop,'个文件：', sFile(:k)
End Subroutine ToDoOneFile

kyra

但是 GetShortFileName 可以实现这个目的。

kyra

你的IVF可能版本比较早，没有导入这个函数。你需要手动导入。

[Fortran] 纯文本查看 复制代码

Subroutine ToDoOneFile( cFile , iLoop )
  use , intrinsic :: ISO_C_Binding
  
  INTERFACE
    FUNCTION GetShortPathName(lpszLongPath,lpszShortPath,cchBuffer)
      import
      integer :: GetShortPathName ! DWORD
      !DEC$ ATTRIBUTES DEFAULT, STDCALL, DECORATE, ALIAS:'GetShortPathNameA' :: GetShortPathName
      !DEC$ ATTRIBUTES REFERENCE, ALLOW_NULL :: lpszLongPath
      character*(*) lpszLongPath ! LPCSTR lpszLongPath
      !DEC$ ATTRIBUTES REFERENCE, ALLOW_NULL :: lpszShortPath
      character*(*) lpszShortPath ! LPSTR lpszShortPath
      integer cchBuffer ! DWORD cchBuffer
    END FUNCTION
  END INTERFACE

   Character( Len = * ) , Intent( IN ) :: cFile
   Integer , Intent( IN ) :: iLoop
   integer :: k
   character(len=512) :: sFile
   k = GetShortPathName( trim(cFile)//c_null_char , sFile , len(sFile) ) 
   Write( * , * ) '第',iLoop,'个文件：', sFile(:k)
End Subroutine ToDoOneFile

kyra

截图或拍照

kyra

那就不知道为啥了。反正我这里是OK的。

你试试自己操作字符串改名吧。

kyra

你需要在 ToDoOneFile 函数中完成重命名，因为它收到的文件名是绝对路径的。而 stInfo.Name 是相对路径。