从C传递数组到Fortran

pasuka

问题：
从C传递数组到Fortran，分别通过interface定义了subroutine和function的形式，前者未起作用，而后者却可以
编译器：gcc/gfortran 4.7&4.8
fortran代码：

[Fortran] 纯文本查看 复制代码

module dynamic
use,intrinsic::iso_c_binding
implicit none
interface
	! Method 1: pass array via subroutine
	subroutine dynamic_array(length,a,n)bind(c,name='dynamic_array')
	import
	implicit none
	integer(c_int),intent(in),value::length
	integer(c_int),intent(out)::n
	type(c_ptr),intent(out)::a
	end subroutine
	! Mehtod 2: pass array via funciton
	type(c_ptr) function dynamic_array2(length,n)bind(c,name='d_array')
	import
	implicit none
	integer(c_int),intent(in),value::length
	integer(c_int),intent(out)::n
	end function
end interface
end module
program test
use dynamic
implicit none
real,pointer::array(:)
type(c_ptr)::c_array
real(c_float),allocatable::array2(:)
integer::i,j
! Initialize pointer
nullify(array)
c_array=c_null_ptr

i=10
j=0
! Method 1
! not worked
call dynamic_array(i,c_array,j)

call c_f_pointer(c_array,array,[j])
write(*,'(A)')"Pass by subroutine"
write(*,'(A,i4)')"Len of array:",j
write(*,'(A)')"Array values:"
write(*,*)array
c_array=c_null_ptr
array=>null()

i = 10
j = 0
! Method2
! worked
c_array = dynamic_array2(i,j)
call c_f_pointer(c_array,array,[j])
write(*,'(A)')"Pass by function"
write(*,'(A,i4)')"Len of array:",j
write(*,'(A)')"Array values:"
write(*,*)array
c_array=c_null_ptr
array=>null()

end program 

C代码：

[C] 纯文本查看 复制代码

#include <stdlib.h>
#include <stdio.h>
/* float array printing function */ 
void print_float_array(float *array, int len) 
{ 
    int i;
    for(i=0; i<len; i++) 
        printf("%f | ", array[i]);
    putchar('\n');
}

void dynamic_array(int n1,float *a,int *n2)
{
	int i;
	// allocate array
	a = (float*)malloc(n1*2*sizeof(float));
	// set values of array
	for(i=0;i<n1*2;i++){a[i] = (float)i*i+1.0;}
	//print_float_array(a,n1*2);
	// set length of array
	*n2 = 20;
}

float* d_array(int n1,int *n2)
{
	int i;
	float *a;
	// allocate array
	a = (float*)malloc(n1*2*sizeof(float));
	// set value
	for(i=0;i<n1*2;i++){a[i] = (float)i*i+1.0;}
	//print_float_array(a,n1*2);
	// set len of array
	*n2 = 20;
	return a;
}

楚香饭

我把 float *a 改成 float **a 以后就可以正常运行了。

因为平时用 Binding 模块少，不太清楚具体如何规定。但是跟踪调试发现，c_ptr 实际上是一个有一个指针成员的结构体，因为 Fortran 传递是传址的。所以指针的地址，就是指针的指针。故而，c 里面应该用 float **a

仅站在 C 语言的角度，如果函数内分配空间，传递给调用者，也必须用指针的指针。


第二个程序用function就正常。那是因为fortran对返回值并不做任何处理，返回什么，就当什么。
d_array 中 a 是指针，返回Fortran以后，它依然是指针，于是 c_array 指针指向正确。

总结来说，Fortran调用一个函数，给它一个参数，一定是参数的地址（传址）。而被调用者返还的返回值，则不做处理。

[C] 纯文本查看 复制代码

void dynamic_array(int n1, float **a, int *n2)
{
  int i;
  // allocate array
  *a = (float*)malloc(n1 * 2 * sizeof(float));
  // set values of array
  for (i = 0; i<n1 * 2; i++){ (*a)[i] = (float)i*i + 1.0; }
  //print_float_array(a,n1*2);
  // set length of array
  *n2 = 20;
}

jason388

chuxf 发表于 2014-3-13 00:43
我把 float *a 改成 float **a 以后就可以正常运行了。

因为平时用 Binding 模块少，不太清楚具体如何规定 ...

type(c_ptr),value 对应C的 void*，type(c_ptr)对应C的 void**，详见gfortran的manual。

pasuka

chuxf 发表于 2014-3-13 00:43
我把 float *a 改成 float **a 以后就可以正常运行了。

因为平时用 Binding 模块少，不太清楚具体如何规定 ...

多谢达人
终于搞明白这个问题了

jason388

即使运行正常也不应该像楼主这样使用。无论是Fortran还是C的动态内存分配，一般均应该分配/释放成对使用，以避免内存泄漏。因此，如果主程序为Fortran，则全局变量的内存分配和释放应该由Fortran负责，同样如果主程序为C则全局变量的内存分配和释放应该由C负责，当然函数内的局部变量的内存分配和释放不在此列。

按Fortran2003标准，Fortran的可分配数组和指针与C是不能互操作的，但TS 29113 Further Interoperability of Fortran with C通过ISO_Fortran_binding.h等使这些限制得以消除，遗憾的是目前gfotran还不能完全支持TS29113.

楚香饭

楼上说得很对，谁申请，谁释放；谁打开，谁关闭。这样才不容易出错。

andy8496

从此坑中爬出来的福友路过！